Performance optimizations or not, every prior version suffering from multiple security vulnerabilities makes for a compelling case to keep up with nVidia driver updates.

Unfortunately, recent versions of nVidia GeForce drivers now include telemetry spyware, even if the optional GeForce Experience bloatware is not installed.

The background

There is an option to Allow Experience Improvement Program under the Help menu in nVidia Control Panel that is enabled by default (of course) but it’s unclear whether disabling it is really sufficient to switch the telemetry off.

Making sure that nVidia spyware is prevented from running takes more than that. Although it can still be done via the GUI with just the Task Scheduler, the MMC Services applet, and RegEdit, having to go through the menus and dialogs to reapply these manually with every update can be annoying, as new driver versions get released frequently.

The solution

To address the issue comprehensively I wrote a simple batch script, unVidia.bat, that helps to get rid of all the sneaky stuff running in the background:

@echo off

rem unVidia.bat
rem Disable nVidia Telemetry

rem Author: Piotr Szczepanski
rem Comments & Updates: http://www.piotr.szczepanski.name/tech/nvidia-geforce-disable-telemetry/

setlocal

call :DisableImage NvProfileUpdater64.exe
call :DisableImage NvTelemetryContainer.exe
call :DisableImage NvTmMon.exe
call :DisableImage NvTmRep.exe
call :DisableService NvTelemetryContainer
call :DisableTaskLike NvProfileUpdater
call :DisableTaskLike NvTm

goto end

:DisableImage
echo * %~1
reg add "HKLM\SOFTWARE\Microsoft\Windows NT\CurrentVersion\Image File Execution Options\%~1" /v Debugger /d "B:\NoVidia.exe" /f >nul 2>&1
exit /b

:DisableService
echo * %~1
net stop "%~1" >nul 2>&1
sc config "%~1" start= disabled >nul 2>&1
exit /b

:DisableTask
echo * %~1
schtasks /Change /TN "%~1" /Disable >nul 2>&1
exit /b

:DisableTaskLike
echo * %~1*
for /f "tokens=1 delims=," %%t in ('schtasks /Query /FO CSV ^| find /v "TaskName" ^| find "%~1"') do call :DisableTask "%%~t"
exit /b

:end

The content should be self-explanatory, except perhaps for the trick disabling the execution of an image by associating it with a nonexistent debugger. Alternatively, instead of the last step, the telemetry executables can be replaced with a dummy .exe file that does nothing.

Run it as an administrator once after the installation completes, and enjoy the drivers for your overpriced GPU free from spyware, whether planted by hackers exploiting security holes (in older versions), or by the manufacturer themselves (in newer versions).

Note: There are probably additional things to switch off if the optional GeForce Experience component is installed but I don’t install it so I don’t know.